How to prevent batch file from terminating

frankzappa77 · Apr 5, 2009

Whenever I write a batch script that provides options using 'if' statements, and input a semicolon, it terminates unexpectedly. Is there a way to prevent this?

For example:

Code:

@echo off

:main
cls
echo Type 'p' or '1' to print a message
echo.
set /p ch=
    if /I %ch%==p (
        cls
        echo Hello
        echo.
        pause
        goto main
    ) 
    if %ch%==1 (
        cls
        echo Hello again
        echo.
        pause
        goto main
    ) else (
        cls
        echo '%ch%' is not a valid parameter
        echo.
        pause
        goto main
    )

If I type in ';' as input, the batch file will close without prompting me that '%ch% is not a valid parameter'.

I tried calling the batch file from within command prompt and it gives me this error:

Code:

Type 'p' or '1' to print a message

;
( was unexpected at this time.

C:\>

Is there a way I can write the batch file so that it doesn't terminate when I have a semicolon in the input?

H2SO4 · Apr 6, 2009

Interesting. That's probably a bug. The error message suggests that your compound statement delimiter '(' was interpreted as part of the IF statement condition.

I played around with your script sample and the following throws a different (though no less useless) error message:

if /I %ch%==p
(
cls
echo Hello
echo.
pause
goto main
)

When it's on the next line, the parenthesis is apparently no longer in danger of becoming misinterpreted as part of the condition. I suspect that semi-colons may be getting handled differently due to their special status in path variables.

I'd suggest lodging this with MS.

Dwarf · Apr 7, 2009

Hi Frank,

Basically, certain characters are known as 'delimiters', and that is why you are getting an error. To avoid this, you need to use quotation marks around the variables i.e. "%ch%" instead of %ch% as shown in the following code:

Code:

:main
cls
echo Type 'a', 'b', or 'c' to print a message or 'exit' to exit
echo.
set /p ch=
echo %ch%
echo.
pause
if /I "%ch%"=="exit" goto exit
if /I "%ch%"=="a" (
cls
echo Hello
echo.
pause
goto main )
if /I "%ch%"=="b" (
cls
echo Hello Again
echo.
pause
goto main )
if /I "%ch%"=="c" (
cls
echo And Hello Yet Again
echo.
pause
goto main )
cls
echo %ch% Is Not a Valid Character
echo.
pause
goto main
:exit
cls
echo Exiting
echo.
pause

frankzappa77 · Apr 7, 2009

Wow thanks a lot for that. I was reading a tutorial on batch and read that a semicolon could be used for comments so I just guessed that even as input, the semicolon would act as a comment and the script would just continue to the next line.

I was also wondering, if I have a blank line between 2 commands, would the script without the space run faster?

For example:

Code:

@echo off
taskkill /f /im explorer.exe

Code:

@echo off

taskkill /f /im explorer.exe

Would the first script run faster than the second, or does it not make a difference?

Dwarf · Apr 7, 2009

It makes absolutely no difference whatsoever to the speed that a script executes, the only difference is that it might be easier to read and debug.

frankzappa77 · Apr 7, 2009

Hmm, it seems that typing double quotes as input, even after applying the fix you suggested, causes the script to crash.

Nothing to worry about I guess, seeing as it's harder to accidentally type " than it is to type ;.

H2SO4 · Apr 8, 2009

Nice one Dwarf. I didn't realise the command shell could allow escape out of the conditional processing in that manner. Rep time.

Dwarf · Apr 8, 2009

frankzappa77 said:
Hmm, it seems that typing double quotes as input, even after applying the fix you suggested, causes the script to crash.

Nothing to worry about I guess, seeing as it's harder to accidentally type " than it is to type ;.

You're welcome, Frank. Yes, this does seem to be a limitation of the relatively simple and limited facilities of the batch file scripting.

frankzappa77 · Dec 23, 2009

I seem to have found a solution to my second problem (explained in post #6). I'm adding the reply to this thread so that the solution's in context.

Here's an interactive example you can try out:

Code:

@echo off

:main
cls
echo                 Main Menu
echo.
echo (0) Type me
echo (1) Or me
echo.
echo (e) Exit
echo.
set mn=null
set /p mn=
set mn=%mn:"=null%
    if "%mn%"=="0" (
        cls
        echo Hello
        echo.
        pause
        goto main
    )
    if "%mn%"=="1" (
        cls
        echo Hello again
        echo.
        pause
        goto main
    )
    if /I "%mn%"=="e" (
        exit
    ) else (
        cls
        echo Not a valid parameter
        echo.
        pause
        goto main
    )

Basically what I did was before processing the input, search it for any quotation marks (") and convert them to something acceptable; "null" in this case. This is the line that does it:

Code:

set mn=%mn:"=null%

What it does is make the variable equal to itself substituting what's after the colon for what's after the equal sign, in this case, a quotation mark for 'null' (you can make 'null' anything you want, I just set it as null so I remember what its purpose is).

So for example, if your input was ' 1" ' (without the enclosing quotation marks), it would become ' 1null ' and then be tested against the if statements.

The reason I have this line:

Code:

set mn=null

before assigning user input to the variable is so that if the user types '1' and it loops back, the variable will be reset to 'null'. If I didn't reset it and hit enter without any input, the old value of '1' would remain and it would execute the same commands again.

Hope this helps.

How to prevent batch file from terminating

frankzappa77

My Computer

System One

H2SO4

A bit of a numpty

My Computer

System One

Dwarf

The Contemplator

My Computer

System One

frankzappa77

My Computer

System One

Dwarf

The Contemplator

My Computer

System One

frankzappa77

My Computer

System One

H2SO4

A bit of a numpty

My Computer

System One

Dwarf

The Contemplator

My Computer

System One

frankzappa77

My Computer

System One